步驟4.創建插件實現的任務:上傳版本信息

class UploadTask extends DefaultTask{
    String url = 'http://127.0.0.1/api/v3/upload/version'
    @TaskAction
    void upload(){
        //1.獲取版本信息
        def version = getCurrentVersion()
        //2.發送版本信息
        def response = sendAndReceive(version)
        //3.處理響應：將版本信息以及響應寫入到本地文件中
//        checkResponse(response)

    }
    //1.獲取版本信息
    def getCurrentVersion(){
        def name = project.extensions.versionInfo.versionName
        def code = project.extensions.versionInfo.versionCode
        def info = project.extensions.versionInfo.versionUpdateInfo
        println "name:$name code:$code info:$info"
        return new VersionInfo(versionName: name,
                     versionCode: code,
                     versionUpdateInfo: info)
    }
    //2.發送版本信息
    void sendAndReceive(VersionInfo version){
        OkHttpClient client = new OkHttpClient()
        FormBody body = new FormBody.Builder()
                .add('versionName',version.versionName)
                .add('versionCode',""+version.versionCode)
                .add('versionUpdateInfo',version.versionUpdateInfo)
                .build()
        Request.Builder builder = new Request.Builder()
                .url(url)
                .post(body)

        def call1 = client.newCall(builder.build())
        call1.enqueue(new Callback() {
            @Override
            void onFailure(@NotNull Call call, @NotNull IOException e) {
                println "push version fail:reason:"+e.message
            }

            @Override
            void onResponse(@NotNull Call call, @NotNull Response response) throws IOException {
                checkResponse(response);
            }
        })
    }
    //3.處理響應：將版本信息以及響應寫入到本地文件中
    void  checkResponse(response){
        println "response:"+new String(response.body().bytes())

    }
}

記住，在需要執行的方法上面添加TaskAction注解：在我們任務執行的時候就會執行到這個方法。

步驟5.將插件擴展和插件任務集成到Project生命周期中

@Override
void apply(Project project) {
    println "begin:now this is a ${project.name} 's upload plugin"
    //1.在插件中引入extensions中的字段，就是我們Project中配置的擴展字段
    project.extensions.create(EXTENSIVE,VersionInfo.class)
    //2.創建待處理的Task
    project.tasks.create(TASK_NAME,UploadTask.class)
    //3.將uploadTask任務掛架到Project的生命周期中
    def build = project.tasks.getByName('clean')
    def uploadTask = project.tasks.getByName(TASK_NAME)
    //這里使用dependsOn強依賴任務關系
    build.dependsOn(uploadTask)
}

步驟6.插件發布

筆者為了測試，將jar包只發布在本地，測試使用。

使用如下方式發布：

gradlePlugin {
    plugins {
        modularPlugin {
                id = 'com.yuhb.upload'
                implementationClass = 'com.yuhb.upload.UploadVersionPlugin'
        }
    }
}

這個配置在build后自動生成resources文件：這個插件擴展配置是引入的：java-gradle-plugin中。

resources文件自動生成.png

當然也可以直接在resources文件夾中上手動寫入該文件

在插件的build.gradle實現下面的邏輯：

uploadArchives {
    repositories {
            mavenDeployer {
                    repository(url:uri('D:/maven_local'))
                    pom.groupId = 'com.yuhb.upload'
                    pom.artifactId = 'uploader'
                    pom.version = '1.0.0'
            }
    }
}

在命令行執行：

./gradlew :uploadversion:uploadArchives

然后去本地文件夾下面看看是否上傳成功：

本地文件成功.png

這里要說明下：

一般情況下都會將自定義插件發布到maven私服或者中央倉庫，才可以供其他項目使用

關于如何發布到maven私服，可以查看這篇文章

后期也會出一期文章教大家如何將數據發布到中央倉庫

步驟7.插件引入

• 步驟1 ：在工程的根build.gradle文件中引入：

buildscript {
        repositories {
                ...
                maven {
                        url uri('D:/maven_local')
                }
        }
        dependencies {
                ...
                classpath 'com.yuhb.upload:upload:1.0.0'
        }
}

說明：

com.yuhb.upload:uploader:1.0.0格式：

• 步驟2 ：在子Project中引入插件：

apply plugin: 'com.yuhb.upload'

• 步驟3 ：配置extensive插件擴展：

versionInfo {
    versionName = '1.0.0'
    versionCode = 1
    versionUpdateInfo = '當前是第一個版本：初始apk'
}

這個versionInfo擴展是怎么來的呢？

我們看下之前我們配置插件的時候，使用了：

EXTENSIVE = 'versionInfo'
project.extensions.create(EXTENSIVE,VersionInfo.class)

在插件中引入extensions中的字段，就是我們Project中配置的擴展字段：

versionInfo {
    versionName = '1.0.0'
    versionCode = 1
    versionUpdateInfo = '當前是第一個版本：初始apk'
}

就是這里，如果外部配置了versionInfo的擴展字段，就會通過project.extensions獲取到，并將數據寫入project.extensions的versionInfo屬性中：之后就可以使用project.extensions的versionInfo屬性訪問外部傳入的配置數據:

def name = project.extensions.versionInfo.versionName
def code = project.extensions.versionInfo.versionCode
def info = project.extensions.versionInfo.versionUpdateInfo

• 步驟4 ：運行root的build 任務查看編譯信息：

./gradlew build

結果：
> Task :app:uploadTask
name:1.0.0 code:1 info:當前是第一個版本：初始apk

這里運行build可以執行插件中的任務是因為前面筆者將插件Task掛接到了build任務之前：

掛接代碼：

//3.將uploadTask任務掛架到Project的生命周期中
def build = project.tasks.getByName('build')
def uploadTask = project.tasks.getByName(TASK_NAME)
//這里使用dependsOn強依賴任務關系
build.dependsOn(uploadTask)

項目Demo完整代碼已經上傳Github：

https://github.com/ByteYuhb/a_gradle_plugin_sample

5.總結

本文主要針對我們自定義插件定義以及優勢做了一些說明，且使用一個實戰項目對自定義插件制作，發布，引入流程做了一個詳細的講解

，Gradle插件部分還有Gradle的上傳流程和AGP插件講解沒有講，后面都會陸續推出。

參考資料

• Gradle自定義插件

  _官網文檔

• Using Gradle Plugins _ Gradle 官方文檔

• Gradle 系列（2）手把手帶你自定義 Gradle 插件_胡飛洋

好了，本文就講解到這里了。