1-保存環境

FIQ中斷觸發時， PE將異常發生時的PSTATE保存到SPSR_EL3 ， 將返回地址保存到ELR_EL3（以上是由硬件完成的） ，（ pstate可能指CPU忙時的電源管理，也可能是其它的，但是肯定關于此時CPU狀態的。）然后跳轉到異常向量 表入口處執行中斷處理流程 。

2-執行中斷處理流程

fiq_aarch64函數主要由handle_interrupt_exception宏實現，該宏的定義如下：

該函數主要實現了

• ? 1、 異常切換時的上下文保存 ，
• ? 2、運行時棧的切換
• ? 3、 中斷處理函數查詢 、
• ? 4、參數設置和跳轉功能。

其詳細流程如下：

.macro handle_interrupt_exception label
    bl save_gp_pmcr_pauth_regs                                         （1）
（1）將通用寄存器（x0 – x29以及sp_el0），pmcr以及pauth寄存器保存到sp_el3指定的el3棧中

#if ENABLE_PAUTH
    /* Load and program APIAKey firmware key */
    bl pauth_load_bl31_apiakey
#endif

    mrs x0, spsr_el3
    mrs x1, elr_el3
    stp x0, x1, [sp, #CTX_EL3STATE_OFFSET + CTX_SPSR_EL3]                （2）
    （2）將spsr_el3和elr_el3保存到sp_el3指定的el3棧中

    /* Switch to the runtime stack i.e. SP_EL0 */
    ldr x2, [sp, #CTX_EL3STATE_OFFSET + CTX_RUNTIME_SP]             （3）
（3）從el3棧中讀取sp_el0棧指針

    mov x20, sp                                                       （4）
（4）將sp_el3棧指針暫存到x20寄存器中

    msr spsel, #MODE_SP_EL0                                          （5）
（5）將當前的runtime棧切換為sp_el0

    mov sp, x2                                                        （6）
（6）恢復sp_el0棧的值

    bl plat_ic_get_pending_interrupt_type                              （7）
（7）讀取當前中斷的中斷號，并根據中斷號獲取中斷類型


    cmp x0, #INTR_TYPE_INVAL
    b.eq interrupt_exit_label                                          （8）
（8）若中斷類型為非法，則直接退出中斷處理


    bl get_interrupt_type_handler                                     （9）
（9）獲取該中斷類型對應的處理函數

    cbz x0, interrupt_exit_label                                       （10）
（10）若獲取處理函數失敗，則直接退出中斷處理

    mov x21, x0                                                      （11）
（11）將中斷類型處理函數指針暫存到x21寄存器中


    mov x0, #INTR_ID_UNAVAILABLE

    /* Set the current security state in the 'flags' parameter */
    mrs x2, scr_el3
    ubfx x1, x2, #0, #1                                                （12）
（12）設置中斷處理函數的輸入參數0和參數1


    /* Restore the reference to the 'handle' i.e. SP_EL3 */
    mov x2, x20                                                      （13）
（13）將sp_el3指針設置中斷處理函數的輸入參數2


    /* x3 will point to a cookie (not used now) */
    mov x3, xzr                                                     （14）
（14）設置中斷處理函數的輸入參數3，該參數始終當前為0


    /* Call the interrupt type handler */
    blr x21                                                         （15）
（15）跳轉到中斷處理函數并執行實際的中斷處理


interrupt_exit_label:                                              
    /* Return from exception, possibly in a different security state */
    b el3_exit

    .endm

（1）將通用寄存器（x0 – x29以及sp_el0），pmcr以及pauth寄存器保存到sp_el3指定的el3棧中

（2）將spsr_el3和elr_el3保存到sp_el3指定的el3棧中

（3）從el3棧中讀取sp_el0棧指針

（4）將sp_el3棧指針暫存到x20寄存器中

（5）將當前的runtime棧切換為sp_el0

（6）恢復sp_el0棧的值

（7）讀取當前中斷的中斷號，并根據中斷號獲取中斷類型

（8）若中斷類型為非法，則直接退出中斷處理

（9）獲取該中斷類型對應的處理函數

（10）若獲取處理函數失敗，則直接退出中斷處理

（11）將中斷類型處理函數指針暫存到x21寄存器中

（12）設置中斷處理函數的輸入參數0和參數1

（13）將sp_el3指針設置中斷處理函數的輸入參數2

（14）設置中斷處理函數的輸入參數3，該參數始終當前為0

（15）跳轉到中斷處理函數并執行實際的中斷處理

在bl31中實際的中斷處理函數有兩類，group 0中斷和secure group 1中斷。 group 0中斷由exception handler framework（ehf）管理，該框架實現了對bl31中group 0中斷的注冊和管理 ，當前sdei框架使用了這種中斷類型。

而secure EL1中斷一般是bl31為bl32接收并轉發給bl32的 ，如optee在bl31中注冊了一個secure el1中斷處理函數opteed_sel1_interrupt_handler，該函數比較簡單，只是執行了異常等級上下文切換，跳轉到bl32的fiq異常處理入口，將中斷處理轉交給bl32。