電子發燒友App
在微機測控系統中，經常要用到A/D轉換。常用的方法是擴展一塊或多塊A/D采集卡。當模擬量較少或是溫度、壓力等緩變信號場合，采用總線型A/D卡并不是最合適、最經濟的方案。這里介紹一種以GNS97C2051單片機為核心，采用TLC2543 12位串行A/D轉換器構成的采樣模塊，該模塊的采樣數據由單片機串口經電平轉換后送到上位機（IBM PC兼容機）的串口COM1或COM2，形成一種串行數據采集串行數據傳輸的方式。經實踐調試證實：該模塊功耗低、采樣精度高、可靠性好、接口簡便，有一定實用價值。
1 主要器件介紹
1.1 TLC2543串行A/D轉換器
模塊采用TI公司的TLC2543 12位串行A/D轉換器，使用開關電容逐次逼近技術完成A/D轉換過程。由于是串行輸入結構，能夠節省51系列單片機I/O資源，且價格適中。其特點有：
（1）12位分辨率A/D轉換器；
（2）在工作溫度范圍內10μs轉換時間；
（3）11個模擬輸入通道；
（4）3路內置自測試方式；
（5）采樣率為66kbps；
（6）線性誤差+1LSB（max）
（7）有轉換結束（EOC）輸出；
（8）具有單、雙極性輸出；
（9）可編程的MSB或LSB前導；
（10）可編程的輸出數據長度。
TLC2543的引腳排列如圖1所示。圖1中AIN0～AIN10為模擬輸入端； 為片選端；DIN 為串行數據輸入端；DOUT為A/D轉換結果的三態串行輸出端；EOC為轉換結束端；CLK為I/O時鐘；REF+為正基準電壓端；REF-為負基準電壓端；VCC為電源；GND為地。
1.2 GMS97C2051單片機
GMS97C2051是武漢力源公司和韓國LG公司聯合推出的一種性能價格比極高的 8位單片機，其指令系統與MCS-51系列完全兼容。GMS97C2051與AT89C2051兼容（可直接替換），但其性能價格比優于AT89C2051。引腳排列如圖2所示。
1.3 電平轉換器MAX3232
MAX3232為RS-232收發器，簡單易用，單+5V電源供電，僅需外接幾個電容即可完成從TTL電平到RS-232電平的轉換。
2 硬件設計
硬件電路如圖4所示。
單片機GMS97C2051是整個系統的核心，TLC2543對輸入的模擬信號進行采集，轉換結果由單片機通過P3.5（9腳）接收，AD芯片的通道選擇和方式數據通過P3.4（8腳）輸入到其內部的一個8位地址和控制寄存器，單片機采集的數據通過串口（3、2腳）經MAX3232轉換成RS232電平向上位機傳輸。圖中串行LCD顯示電路僅用于調試，對采集/傳輸的數據進行監測。
3 單片機軟件設計
單片機程序主要包括串行數據采集模塊“DATA_SAM”和串行數據傳輸模塊“RS232”，調試所用到的顯示子程序在此略去。
TLC2543的通道選擇和方式數據為8位，其功能為：D7、D6、D5和D4用來選擇要求轉換的通道，D7D6D5D4=0000時選擇0通道，D7D6D5D4=0001時選擇1通道，依次類推；D3和D2用來選擇輸出數據長度，本程序選擇輸出數據長度為12位，即D3D2=00或D3D2=10；D1，D0選擇輸入數據的導前位，D1D0=00選擇高位導前。
TLC2543在每次I/O周期讀取的數據都是上次轉換的結果，當前的轉換結果在下一個I/O周期中被串行移出。第一次讀數由于內部調整，讀取的轉換結果可能不準確，應丟棄。
數據采集程序如下：
DATA_SAM：
MOV R0，#30H ；數據緩沖區首地址30H→R0
MOV R1，#00000000B ；0通道方式/通道數據
ACALL RD_AD ；第一次讀取的轉換結果可能不準確，丟棄。
MOV R1，#00010000B ；1通道方式/通道數據
ACALL RD_AD ；送1通道方式/通道數據并讀第0通道轉換結果
MOV @R0，R2 ；轉換結果存放到數據緩沖區，下同
INC R0
MOV @R0，R3
INC R0
MOV R1，#00100000B ；2通道方式/通道數據
ACALL RD_AD ；送2通道方式/通道數據并讀第1通道轉換結果
MOV @R0，R2
INC R0
MOV @RO，R3
INC R0
………… ；其它通道操作方式類推
RET
單片機通過編程產生串行時鐘，并按時序發送與接收數據位，完成通道方式/通道數據的寫入和轉換結果的讀出，程序如下，供數據采集模塊“DATA_SAM” 調用。
CLK EQU P3.3
DIN EQU P3.4
DOUT EQU P3.5
CS EQU P3.7
RD_AD：
CLR CLK ；清I/O時鐘
SETB CS ；設置片選為高
CLR CS ；設置片選為低
MOV R4，#08 ；先讀高8位
MOV A， R1 ；把方式/通道控制字放到A
LOP1：
MOV C，DOUT ；讀轉換結果
RLC A ；A寄存器左移，移入結果數據位，移出方式/通道控制位
MOV DIN，C ；輸出方式/通道位
SETB CLK ；設置I/O時鐘為高
CLR CLK ；清I/O時鐘
DJNZ R4，LOP1 ；R4不為0，則返回LOP1
MOV R2，A ；轉換結果的高8位放到R2中
MOV A，#00H ；復位A寄存器
MOV R4，#04 ；再讀低4位
LOP2：
MOV C，DOUT ；讀轉換結果
RLC A ；A寄存器左移，移入結果數據位
SETB CLK ；設置I/O時鐘為高
CLR CLK ；清I/O時鐘
DJNZ R4，LOP2 ；R4不為0，則返回LOP2
MOV R3，A ；轉換結果的低4位放到R3中
SETB CS ；設置片選為高
RET
串行數據傳輸模塊包括串行口初始化子程序和數據傳輸子程序，各子程序分別如下。其中數據傳輸采用查詢方式，也可以方便地改為中斷方式。
INIT_COM：
MOV SCON，#50H ；串口方式1工作，8位數據位，1位停止位，無奇偶校驗
MOV PCON，#80H ；SMOD=1，波特率增倍
MOV TMOD，#20H ；波特率設置，fOSC=12MHz，波特率=2* 2400，N=0F3H
MOV TH1，#0F3H
MOV TL1，#0F3H
SETB TR1 ；啟動定時器T1
RET
RS232：
MOV R0，#30H ；緩沖區首地址30H→R0
MOV R5，#22 ；發送數據長度→R5，11* 2=22
LOOP：
MOV A，@R0 ；取數據→A
MOV SBUF，A ；數據→SBUF
WAIT：
JBC TI，CONT ；判斷發送中斷標志，是1則轉到CONT，并清TI
SJMP WAIT
CONT：
INC R0
DJNZ R5，LOOP
RET
4 上位機串口接收程序設計
上位機接收數據所用C語言程序包括初始化子程序和接收子程序。各子程序分別如下：
void init_com1（void） /*初始化子程序*/
{
outportb（0x3fb，0x80）; /*線控制寄存器高位置1，使波特率設置有效*/
outportb（0x3f8，0x18）; /*波特率設置，與單片機波特率一致為4800bps*/
outportb（0x3f9，0x00）;
outportb（0x3fb，0x03）; /*線控制寄存器設置，8位數據位，1位停止位，無奇偶校驗*/
outportb（0x3fc，0x03）; /*Modem控制寄存器設置，使DTR和RTS輸出有效*/
outportb（0x3f9，0x00）; /*設置中斷允許寄存器，禁止一切中斷*/
}
void receive_data（void） /*查詢方式接收數據子程序*/
{
while（！kbhit（））
{
while（！（inportb（0x3fd）&0x01））;/*若接收寄存器為空，則等待*/
printf（“%x ”，inportb（0x3f8））; /*讀取結果并顯示*/
}
getch（）;
}
5 結論
本文給出的硬件和軟件均經過實踐檢驗，并且已經按照PC/104總線制作成數據采集卡，使用很方便，能夠滿足對數據采樣頻率要求不是特別高的應用場合。
責任編輯；zl
工商網監
評論