串行數模轉換實驗

一． 實驗目的
學會使用D/A 轉換器生成用戶所需要的波形。
二． 實驗設備及器件
IBM PC 機 一臺
DP-51PROC 單片機綜合仿真實驗儀 一臺
雙蹤示波器 一臺
三． 實驗內容
1． 設計軟件程序，用單片機的I/O 口控制TLC5620 實現D/A 轉換，使其通道1 產
生一個三角波，而通道2 產生一個和通道1 周期、幅度均相同的方波。
2． 連接線路，調整TLC5620 的參考電壓為2.6V，運行程序，用雙蹤示波器觀察產生
的波形。
四． 實驗要求
實驗前閱讀有關TLC5620 的數據手冊，并了解TLC5620 的4 種時序圖，以及產
生波形幅度的計算方法。
五． 實驗步驟
1． 短接B7 區的電源供給跳線JP16，調節B7 區的電位器W3，使其輸出接線柱Verf
的電壓為2.6V。
2． 將A2 區P16、P17、T0、T1 分別連接到B9 區的CLK、DAT、LDAC、LOAD，
將B7 區Verf 連接到B9 區REF 接線柱，短接B9 區電源跳線JP13。
3． 運行光盤中的相應程序，用雙蹤示波器的兩個探頭觀察DACA、DACB 輸出的波形。
六． 實驗預習要求
認真預習本節實驗內容，按照實驗的要求提前做好實驗準備工作。
七． 實驗參考程序
SCLA BIT P1.6
SDAA BIT P1.7
LOAD BIT P3.5
LDAC BIT P3.4
VOUTA DATA 30H
VOUTB DATA 31H
ORG 8000H
AJMP MAIN
ORG 8100H

MAIN:
MOV SP,#60H
NOP
CLR SCLA
CLR SDAA
SETB LOAD
SETB LDAC
MOV R3,#0A2H
MOV R4,#00H
MOV VOUTA,#00H
MOV R5,#0A2H
MOV R6,#00H
MOV VOUTB,#00H
DACHANG:
MOV R1,#01H
MOV R2,VOUTA
LCALL DAC5620
DJNZ R3,CONTINUEA
MOV R3,#0A2H
MOV A,R4
CPL A
MOV R4,A
CONTINUEA:
CJNE R4,#0FFH,CONTINUEB
DEC R2
SJMP CONTINUEC
CONTINUEB:
INC R2
CONTINUEC:
MOV VOUTA,R2
MOV R1,#03H
MOV R2,VOUTB
LCALL DAC5620
DJNZ R5,CONTINUED
MOV R5,#0A2H
MOV A,R6
CPL A
MOV R6,A
CONTINUED:
CJNE R6,#0FFH,CONTINUEE
MOV R2,#0A2H
SJMP CONTINUEF
CONTINUEE:
MOV R2,#00H

CONTINUEF:
MOV VOUTB,R2
LJMP DACHANG
;=============================================
; 函數名稱: DAC5620
; 功能描述: TI 公司8 位4 通DAC 芯片TLC5620 的控制時序
; 入口參數: R1(通道選擇和幅度增量)、R2(轉換電壓的數字值，公式中的CODE)
; 出口參數: 無
; 占用資源: ACC、R1、R2
; 全局變量: 無
; 調用模塊: SENDBYTE
; 日 期: 2004-10-27
; 備 注: 使用雙8 位傳輸控制模式，使用LDAC 下降沿鎖存數據輸入
;=============================================
DAC5620:
MOV A,R1
CLR SCLA
MOV R7,#08H
LCALL SENDBYTE
MOV A,R2
CLR SCLA
MOV R7,#08H
LCALL SENDBYTE
CLR LOAD
SETB LOAD
CLR LDAC
SETB LDAC
RET
SENDBYTE:
SETB SCLA
RLC A
MOV SDAA,C
CLR SCLA
DJNZ R7,SENDBYTE
RET
END